Erste Experimente mit der GND

Die Gemeinsame Normdatei (GND) enthält unter anderem semantische Daten zu Personen und Orten. In diesem Beitrag verwenden wir SPARQL um die Daten und die Ontologie dahinter besser kennen zu lernen.

Wir versuchen mit der GND die folgende Frage zu beantworten:

Welche Berufe gab es Nürnberg im 17. Jahrhundert.

Zur Beantwortung dieser Frage verwenden wir unseren lokalen Apache Jena Server. Die SPARQL-Anfragen können entweder in der Web GUI von Apache Jena ausgeführt werden, oder mit einer der vielen SPARQL-Clients¹.

Lade Beispielperson

In der GND Ontology sind einige Beispiel Entities genannt. Wir laden hier das Beispiel für eine Individualisierte Person der GND ID 118514091.

PREFIX gnd: <https://d-nb.info/gnd/>
PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>

SELECT ?p ?o
WHERE {
  gnd:118514091 ?p ?o .
}

Die Anzahl der Trippel wurde aus Darstellungsgründen gekürzt. Bei der Person handelt es sich um David Bowie. Wir erhalten unter anderem weitere Verweise auf andere Graphen mit Informationen über David Bowie, persönliche Daten über ihn, sowie eine Liste in der GND definierter Berufe und Tätigkeiten, die er ausgeübt hat.

Berufe und Tätigkeiten von David Bowie

Als Nächstes suchen wir die Berufe und Tätigkeiten von David Bowie und berücksichtigen dabei auch alternativen Schreibweisen und Bezeichnungen der Berufe. Dafür verwenden wir die Verbindung professionOrOccupation. Alternativ gibt es die Verbindung professionOrOccupationAsLiteral, die in unseren Tests aber einige fehlerhaft geparste Daten beinhaltete (Zahlen, Buchstaben, …) oder Zusatzinformationen lieferte (z.B. Zeitraum in der eine Tätigkeit ausgeübt wurde). Der Beruf ist in der GND als Schlagwort (engl. subject heading) hinterlegt. Daher holen wir uns für das Schlagwort die bevorzugte Bezeichnung und alternative Bezeichnungen.

PREFIX gnd: <https://d-nb.info/gnd/>
PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>

SELECT DISTINCT ?job
WHERE {
  gnd:118514091 gndo:professionOrOccupation ?jobId .
  ?jobId gndo:preferredNameForTheSubjectHeading|gndo:variantNameForTheSubjectHeading ?job .
}

Musiker, Musikschaffender, Komponist, Tonsetzer, Schauspieler, Darsteller (Schauspieler), Sänger, Konzertsänger, Librettist, Textdichter (Librettist), Bandleader, ld

Zur Übersichtlichkeit haben wir an dieser Stelle eine Listendarstellung für die Ergebnisse gewählt.

Berufe und Tätigkeiten in Nürnberg (fixiert)

Nachdem wir herausgefunden haben, wie wir die Berufe und Tätigkeiten einer Person aus der GND auslesen können, verknüpfen wir diese Information mit einem Ort. Konkret mit dem Ort Nürnberg, welches die GND ID 4042742-0 hat. Hierfür suchen wir zuerst nach Personen, die über eine Auswahl von Eigenschaften (z.B. Geburtsort) mit Nürnberg verknüpft sind und suchen dann nach deren Berufsbezeichnungen.

PREFIX gnd: <https://d-nb.info/gnd/>
PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>

SELECT DISTINCT ?job
WHERE {
  ?person gndo:placeOfBirth|gndo:placeOfDeath|gndo:placeOfActivity|gndo:placeOfExile|gndo:characteristicPlace gnd:4042742-0 ;
          gndo:professionOrOccupation ?jobId .
  ?jobId gndo:preferredNameForTheSubjectHeading|gndo:variantNameForTheSubjectHeading ?job .
}
LIMIT 20

Künstler, Bildender Künstler, Künstlertum, Kunstschaffender, Grafiker, Graphiker, Kupferstecher, Maler, Mathematiker, Diplommathematiker, Zeichner, Musiker, Musikschaffender, Dirigent, Orchesterleiter, Chorleiter, Chorregent, Chordirektor, Chormeister, Chordirigent

Um eine übersichtliche Ergebnismenge zu erhalten, haben wir die Anzahl der Ergebnisse auf 20 limitiert.

Berufe und Tätigkeiten in Nürnberg (frei)

In der letzten Anfrage haben wir die Art der Verknüpfung von Personen mit dem Ort Nürnberg fixiert. Dazu gehört ein intensives Studieren der GND Ontoloy.

Es geht auch einfacher. In der folgenden Anfrage suchen wir nach Personen, die in irgendeiner Beziehung zu Nürnberg stehen (?person ?p gnd:4042742-0) und suchen dann die Berufsbezeichnungen.

Theoretisch erhöhen wir dadurch die Trefferquote, verringern aber die Genauigkeit. Praktisch spielte das in unseren Experimenten keine Rolle.

PREFIX gnd: <https://d-nb.info/gnd/>
PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>

SELECT DISTINCT ?job
WHERE {
  ?person ?p gnd:4042742-0 ;
          gndo:professionOrOccupation ?jobId .
  ?jobId gndo:preferredNameForTheSubjectHeading|gndo:variantNameForTheSubjectHeading ?job .
}
LIMIT 20

Künstler, Bildender Künstler, Künstlertum, Kunstschaffender, Grafiker, Graphiker, Kupferstecher, Maler, Mathematiker, Diplommathematiker, Zeichner, Physiker, Astronom, Astronomen, Kartograf, Kartograph, Pfarrer, Pastor, Evangelischer Theologe, Theologe / Evangelische Kirche

Die Ergebnisse dieser Vorschau unterscheiden sich von der letzten Abfrage, da der Graph in einer anderen Reihenfolge traversiert wird. Vergleicht man die Gesamtmenge der Ergebnisse, dann unterscheiden sie sich nur in der Reihenfolge der Elemente.

Berufe und Tätigkeiten in Nürnberg im 17. Jahrhundert

Um die Anfrage aus dem letzten Beispiel auf das 17. Jahrhundert einzuschränken, fügen wir einen Filter für das Geburtsdatum und das Sterbedatum der Personen hinzu.

Der Vollständigkeit halber, haben wir gndo:dateOfBirth und gndo:dateOfDeath optional gesetzt. Das verhindert, dass wir ungewollt Personen filtern, bei denen eines der beiden Daten fehlt. Daher brauchen wir noch ein extra Filterkriterium, welches das Geburtsdatum nach unten und das Todesdatum nach oben beschränkt².

PREFIX gnd: <https://d-nb.info/gnd/>
PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

SELECT DISTINCT ?job
WHERE {
  ?person ?p gnd:4042742-0 ;
          gndo:professionOrOccupation ?jobId .
  ?jobId gndo:preferredNameForTheSubjectHeading|gndo:variantNameForTheSubjectHeading ?job .
  OPTIONAL { ?person gndo:dateOfBirth ?birthDay . }
  OPTIONAL { ?person gndo:dateOfDeath ?deathDay . }
  FILTER ( bound(?birthDay) || bound(?deathDay) ) .
  FILTER ( bound(?birthDay) && ?birthDay >= "1501-01-01"^^xsd:date && ?birthDay < "1701-01-01"^^xsd:date ) .
  FILTER ( bound(?deathDay) && ?deathDay >= "1601-01-01"^^xsd:date && ?deathDay < "1801-01-01"^^xsd:date ) .
}
LIMIT 20

Kupferstecher, Zeichner, Künstler, Bildender Künstler, Künstlertum, Kunstschaffender, Maler, Radierer, Buchhändler, Buchführer, Drucker, Buchdrucker, Verleger, Verlagsbuchhändler, Verlagsleiter, Musikverleger, Pfarrer, Pastor, Jurist, Rechtswissenschaftler

Methodische Probleme

Bevor wir mit diesen Ergebnissen versuchen spezifische Aussagen zu treffen, sollten wir zuerst einige methodische Probleme betrachten.

💼 Beruf und 🏠 Ort

Die Verknüpfung von Beruf und Ort lässt sich in der GND nur über eine 👤 Person herstellen. Mit den vorliegenden Daten kann jedoch nicht festgestellt werden, ob die 👤 Person den Beruf (oder die Tätigkeit) auch an diesem Ort ausgeübt hat. Zum Beispiel wurde Albert Einstein in Ulm geboren, hat den Beruf des Physikers dort jedoch nie ausgeübt.

📅 Zeit und 🏠 Ort

Mit dem Filter auf Geburtsdatum und Sterbedatum haben wir zwar eine grobe Einschränkung getroffen. Es ist jedoch nicht zu bestimmen, ob eine 👤 Person mit Sterbedatum 1601 ihren Beruf im 17. Jahrhundert noch ausgeübt hat. Es ist sicherlich auszuschließen, dass die meisten 👥 Personen mit einem Geburtsdatum von 1699 ihren Beruf im 17. Jahrhundert schon ausgeübt haben.

📜 Datengrundlage

Die GND beinhaltet (noch) keinen repräsentative Darstellung der Gesamtbevölkerung. Es gibt einen starken Bias in Richtung 👥 Personen, die schriftliche Erzeugnisse produzierten, oder künstlerisch tätig waren. Das wird im folgenden Beispiel deutlich.

Berufe und Tätigkeiten in Nürnberg im 17. Jahrhundert mit Häufigkeit

Anstatt wie zuvor alle Berufe und Tätigkeiten mit alternativen Bezeichnungen zu sammeln, schreiben wir hier eine Auswertung, die die Häufigkeit der einzelnen Berufe und Tätigkeiten bestimmt. Die alternativen Bezeichnungen, werden in einer separaten Spalte der Ausgabetabelle gesammelt.

PREFIX gnd: <https://d-nb.info/gnd/>
PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

SELECT ?job (COUNT(?job) AS ?count) (GROUP_CONCAT(DISTINCT ?jobAlternative; SEPARATOR=", ") AS ?alternatives)
WHERE {
  ?person ?p gnd:4042742-0 ;
             gndo:professionOrOccupation ?jobId .
  ?jobId gndo:preferredNameForTheSubjectHeading ?job ;
         gndo:variantNameForTheSubjectHeading ?jobAlternative .
  OPTIONAL { ?person gndo:dateOfBirth ?birthDay . }
  OPTIONAL { ?person gndo:dateOfDeath ?deathDay . }
  FILTER ( bound(?birthDay) || bound(?deathDay) ) .
  FILTER ( bound(?birthDay) && ?birthDay >= "1501-01-01"^^xsd:date && ?birthDay < "1701-01-01"^^xsd:date ) .
  FILTER ( bound(?deathDay) && ?deathDay >= "1601-01-01"^^xsd:date && ?deathDay < "1801-01-01"^^xsd:date ) .
}
GROUP BY ?job
ORDER BY DESC(?count)

Zur Übersichtlichkeit haben wir die Tabelle auf 10 Einträge reduziert, sie kann als

Wenn man einen Blick auf diese Auswertung wirft, wird schnell klar, dass dies weder eine repräsentative, noch eine vollständige Darstellung der Berufe und Tätigkeiten im 17. Jahrhundert in Nürnberg darstellt. Für unseren Streifzug durch die Daten der GND war die Fragestellung jedoch sehr hilfreich. Und auch im Archivalltag haben wir immer wieder Rechercheaufgaben, in denen konkret nach Personen mit einem bestimmten Beruf gesucht werden, die in einem bestimmten Zeitraum in einer Stadt gelebt haben.